/****************************************************************** 
  * 60-60-60 Planar.pov                                              *
  * Generates a 60-60-60 kaleidoscope with a sports balls image map. *
  * References code by Mark Newbold.                                 *
  ********************************************************************/
  
  global_settings { 
    assumed_gamma 1.8   // for rendering or viewing on a mac 
  }
  global_settings { 
    max_trace_level 25  // maximum number of rays spawned 
  }

  camera {
    location <0, 0, -4> // move camera towards viewer 
    look_at <0, 0, 0>   // position camera to look at the origin
    right x             // specify camera's "right" vector
  }     
  
  #declare image = pigment {
    image_map {
      gif "SportsBalls.gif"  // specify image to be mapped later onto the far plane
      once                   // only map once; do not tile or repeat
    }
  }

  #declare mirrors = union { // specify triangle of mirrors as the union of three infinite planes
    plane { x, 0.245 }
    plane { <cos(2*pi/3), sin(2*pi/3), 0>, 0.245 }
    plane { <cos(4*pi/3), sin(4*pi/3), 0>, 0.245 }
    finish {
      reflection 1           // make all three planes fully reflective (mirrors)
      ambient 0
      specular 0
    }
  }


  union {                    // combine mirrors with image plane to create kaleidoscope object
    plane { <0, 0, -1>, 0
      pigment { image }      // map image onto z-plane
      translate <-0.5, -0.5, 0>
      finish { ambient 1.4 }
      rotate 360*clock*z     // rotate image plane one full turn per clock cycle (see QUICKRES.INI)
    }
    object {
      mirrors
    }
  }